bash/shell

czezz · 02-11-2009, 03:07 AM

I have text like this:
Each part starts with line "case".
Below "case" are 3 sections:
1st - begin with @
2nd - begin with # - this one is not very necessary
3rd - begin with $
last line - begin with details

What I'd like to have is to switch all @-lines to 3rd section and all $-lines to 1st section (switch them)

here is real sample:

Code:

                case "3": ### - blablabla
@Text1 = "blalalal"
@Text2 = "bnothndfds"
@SomeText3 = "adsfdsfds S"
@WhatText = 1
@AgainText = 0
@NoText = @x + @S
                        # some
                        # unnecessary
                        # comments
                        $varible_1 = x
                        $some_other_varible_1 = x
                        details(something)                        
                case "3": ### - xzxzxzxzxzxz
@Text1 = "xxxblalalasl"
@Text2 = "rtybnothndfds"
@SomeText3 = "ereadsfdsfds S"
@WhatText = 1
@AgainText = 0
@NoText = @x + @S
                        # some
                        # unnecessary
                        # comments
                        # with more lines
                        $varible_1 = x
                        $some_other_varible_1 = x
                        $more_varibles = x
                        details(something)

What I need:

Code:

                case "3": ### - blablabla
                        # some
                        # unnecessary
                        # comments
                        $varible_1 = x
                        $some_other_varible_1 = x
@Text1 = "blalalal"
@Text2 = "bnothndfds"
@SomeText3 = "adsfdsfds S"
@WhatText = 1
@AgainText = 0
@NoText = @x + @S
                        details(something)                        
                case "3": ### - xzxzxzxzxzxz
                        # some
                        # unnecessary
                        # comments
                        # with more lines
                        $varible_1 = x
                        $some_other_varible_1 = x
                        $more_varibles = x
@Text1 = "xxxblalalasl"
@Text2 = "rtybnothndfds"
@SomeText3 = "ereadsfdsfds S"
@WhatText = 1
@AgainText = 0
@NoText = @x + @S
                        details(something)

Anyone know how to do this ?

colucix · 02-11-2009, 03:34 AM

Maybe using awk:

Code:

/case/ {

    print
    
    while ( $1 !~ "details" ) {
      getline
      if ( $1 ~ /^@/ ) {
         count0++
         array0[count0] = $0
	 }
      else {
         count1++
         array1[count1] = $0
	 }
    }
    
    # print array1
    for ( i = 1; i <= count1-1; i++ )
        print array1[i]
	
    # print array0
    for ( i = 1; i <= count0; i++ )
        print array0[i]
	
    # print details
    print array1[count1]
	
    # delete arrays
    for ( i in array0 )
        delete array0[i]
    for ( i in array1 )
        delete array1[i]
	
    # reinitialize counters
    count0 = 0
    count1 = 0
    
}

czezz · 02-11-2009, 05:51 AM

Looks good

The only thing is that case lines are duplicated but it is a small problem.

Can I have a little explanation of what is going on in code ?

colucix · 02-11-2009, 07:14 AM

Quote:

Originally Posted by czezz

Looks good

The only thing is that case lines are duplicated but it is a small problem.

This is really strange. Looking at the code there is no way you can get the case line twice, unless you have two consecutive case lines in the original input.

Quote:

Can I have a little explanation of what is going on in code ?

Of course. The whole code starts every time it encounter a line containing the "case" pattern. First it simply print that line, then starts a while loop which ends when it encounters the "details" pattern. This is one of the assumptions: each section should always end with a "details" line.

Then it stores lines in two diffrent arrays. Array0 contains lines which begin with a "@", array1 stores all the rest:

Code:

if ( $1 ~ /^@/ ) {
    array0 is pouplated
    }
else {
    array1 is populated
    }

When the while loop ends, it prints the content of the arrays in revers order: first array1, then array0. All the lines in the array1 are printed except the last one (that one containing "details"), which in turn is printed after array0.

Finally it deletes the content of the arrays and reset the counters. When it encounters the next "case" line the code is run again.

If you have problems with the duplicated case, please attach the actual input file to your post, so I can try to process it on my machine and discover the bug. I don't remember if the ability to attach files is reserved to "Senior Members". Eventually you can e-mail me (you can find a link to send an e-mail in my LQ profile).

ghostdog74 · 02-11-2009, 08:36 AM

Code:

# awk '/^@/{ s=s $0 "\n";next}/details/{ print s; s=""}1' file

colucix · 02-11-2009, 10:26 AM

Quote:

Originally Posted by ghostdog74

Code:

# awk '/^@/{ s=s $0 "\n";next}/details/{ print s; s=""}1' file

ghostdog74 beats colucix 6-0!!! A really impressive one-liner!