[SOLVED] sed: insert a line after matching pattern in two lines. How?

ddenial · 10-23-2022, 12:47 PM

Hello everyone.

Suppose I have a file with the following content:

Code:

$ cat thefile 
one
two
three
four
five

I want to search for the pattern that is spread across two lines and append a line after it. For example, I want to search for the patterns 'two' and 'three,' then append the line 'The new line' after that.

The output should be like this:

Code:

$ cat thefile 
one
two
three
The new line
four
five

I tried this command, and it is not working.

Code:

$ sed '/two\nthree/a\The new line/' thefile

I appreciate any solution.

Thanks

Turbocapitalist · 10-23-2022, 01:47 PM

There are probably several ways to do it, even with sed.

Code:

sed -e '/^two/ { n; /^three/ s/$/\nThe new line/ }' thefile

lvm_ · 10-23-2022, 01:48 PM

Normally sed empties pattern space with each new line, but 'N' command appends next line into the pattern space, if you are determined to do it with sed you'll have to use it. But not me, I would've used awk here.

Code:

gawk '{print} /^one$/{one=1;next} /^two$/{if(one)print "the new line"} {one=0}'

ddenial · 10-23-2022, 02:37 PM

Thank you

MadeInGermany · 10-23-2022, 07:53 PM

Regarding sed:
Normally there is one line in the input buffer, and \n in a RE search does not work.
Only the N command appends another line to the input buffer, with an embedded \n that then can be used in a RE search.

A \n in a substitution string is specific to GNU sed.
A Unix/Posix sed needs the a(ppend) command and multi-line:

Code:

sed '
  /two/ {
    n
    /three/ a\
The new line
  }
' thefile

Code:

sed '
  /two/!b
  n
  /three/ a\
The new line
' thefile